احصل علي باك اب يومي واستلمه من خلال الايميل

السلام عليكم ورحمة الله
تخيل كدا لو انت شغال وفجأه السيرفر حصل فيه مشكلة لأي سبب
المهم المشكله دلوقتي في بيانات العملا و اعدادات السيرفر
لذلك هنستخدم الباك اب
الباك اب دا شامل كل الاعدادات بتاعتك ع سيرفر الميكروتك بما فيهم اسماء العملاء واعدادات الدمج .....الخ
المهم طريقة انهارده هو سكربت هتستخدمه انه يبعتلك باك اب بشكل اوتوماتيك
وطبعا هتستلمه ع الايميل
وبكدا انت ضامن عدم ضياع اعداداتك

--------------------------------------------------------------------------------

 #### Modify these values to match your requirements ####

#Your email address to receive the backups 

:local toemail "you@example.com"
#The From address (you can use your own address if you want)
:local fromemail "mikrotik@example.com"
#A mail server your machines can send through
:local emailserver "smtp.example.com"

############## Don’t edit below this line ##############

:local sysname [/system identity get name]
:local textfilename
:local backupfilename
:local time [/system clock get time]
:local date [/system clock get date]
:local newdate "";
:for i from=0 to=([:len $date]-1) do={ :local tmp [:pick $date $i];
:if ($tmp !="/") do={ :set newdate "$newdate$tmp" }
:if ($tmp ="/") do={}
}
#check for spaces in system identity to replace with underscores
:if ([:find $sysname " "] !=0) do={
:local name $sysname;
:local newname "";
:for i from=0 to=([:len $name]-1) do={ :local tmp [:pick $name $i];
:if ($tmp !=" ") do={ :set newname "$newname$tmp" }
:if ($tmp =" ") do={ :set newname "$newname_" }
}
:set sysname $newname;
}
:set textfilename ($"newdate" . "-" . $"sysname" . ".rsc")
:set backupfilename ($"newdate" . "-" . $"sysname" . ".backup")
:execute [/export file=$"textfilename"]
:execute [/system backup save name=$"backupfilename"]
#Allow time for export to complete
:delay 2s
#email copies
:log info "Emailing backups"
/tool e-mail send to=$"toemail" from=$"fromemail" server=[:resolve $emailserver] port=25 subject="[Config Backup] $sysname $time" file=$"textfilename"
#Send as different subjects to force GMail to treat as new message thread.
:local time [/system clock get time]
/tool e-mail send to=$"toemail" from=$"fromemail" server=[:resolve $emailserver] port=25 subject="[Config Backup] $sysname $time" file=$"backupfilename"
#Allow time to send
:delay 10s
#delete copies
/file remove $textfilename
/file remove $backupfilename

--------------------------------------------------------------------
طبعا متنساش تغير الايميل في الاسكربت لايميلك
وبعدين هتروح لقايمة scheduler وتضيف دا
علشان تحدد الوقت اللي يبعتلك الباك اب
يعني مثلا كل يوم
---------------------------------------------------------------------

/system scheduler
add interval=1d name=daily-backup on-event="/system script run backup-and-email" policy=ftp,reboot,read,write,policy,test,winbox,password,sniff,sensitive,api start-date=jan/01/2014 start-time=04:00:00